The source code of GARFIELD has been altered to eliminate the need for intermediate conversion programs in using GARFIELD output in either GEANT or MOFIA. Documentation of the changes made to the source code of garfield-7 is available here.
    As a result of this new output format, GEANT is able to read in directly the GARFIELD output files. As well, MOFIA now reads in directly the same output file, and then internally generates the STRs in the desired format. More information on the generation of STRs in MOFIA is available here.

 Sample Input file for GARFIELD

Method:
    Define variables characterizing cell conditions
    Define cells
        Define direction of gravity
        Define planes of constant voltage
        Define wires
    Define Magnetic Field
    Define Gas conditions (Usually read in from a file. See Producing Gas Tables for more info.
    Select wire of interest
    Define the area of interest
    Define the grid spacing (Chosen to be 201x201 to match desired format for GEANT and MOFIA)
    Calculate Drift Time Tables (This should be re-directed to a file).

With the present settings in GARFIELD, the limiting grid density is 1000x1000, but BEWARE. The computation time sky-rockets for increasing densities in a fixed area. As well, both GEANT and MOFIA are setup to handle a grid size of 201x201. Changing the grid size will result in incompatabilities that will need to be resolved.

Running GARFIELD on a 550 MHz Pentium III with a grid size of 201x201, took 11.1 minutes to complete the generation of the Drift Time Tables.
 

Last Update: May 25, 2001 by Roy Wilds

*Internal Variables
GLOBAL y=True
GLOBAL n=False

*External use variables

Global GARFUSER=`Santa Claus`
*Global GAS=`DME`
*Global GAS=`AR25_ISO`
Global GAS=`HE70_ISO`

GLOBAL B=0
*GLOBAL B=2.2
GLOBAL t=296
GLOBAL p=760
GLOBAL VOLT=-1500
Global OFILE=`DC_{GAS}_B{B*10}_T{t}_P{p}.dat`
Global gridsize=201

*Adding interactive capablilties. Roy Wilds - May 10, 2001
*If not wanted, remove lines between the bounding ******* lines.
************Verify current values are proper OR get new ones.****************
  say "The current values are:"
  say "User name written to output file= {GARFUSER} "
  say "Bfield= {B}  Temperature= {t}  Pressure= {p}  "
  say "Voltage= {VOLT}  GAS= {GAS}"
  say "MC Output file= {OFILE}"
  say "Grid Size = {gridsize}"
  say "Are these values okay? (y/n)"
  parse Evaluate Terminal choice00
  if choice00 Then
     say "Proceeding with above values"
  Else
     say "New user name for output file="
     parse Terminal GARFUSER
     say "New Bfield="
     parse Terminal B
     say "New Temperature="
     parse Terminal t
     say "New pressure="
     parse Terminal p
    say "New Voltage="
     parse Terminal VOLT
     say "New GAS="
     parse Terminal GAS
     say "New MC Output file="
     parse Terminal OFILE
     say "New Grid Size="
     parse Terminal gridsize
     say " "
     say "The current values are:"
     say "User name written to output file= {GARFUSER} "
     say "Bfield= {B}  Temperature= {t}  Pressure= {p}  "
     say "Voltage= {VOLT}  GAS= {GAS}"
     say "MC Output file= {OFILE}"
     say "Grid Size= {gridsize}"
  Endif
***************************************************************************

&cell
plane y=0.2, v={VOLT}
plane y=-0.2 v={VOLT}
gravity 1 1 0
rows
s  1  0.005   -16.8       0.00   0.     60.  40. 19.4
s  1  0.0025  -16.4       0.000  0.     45.  40. 19.4
s 80  0.0015  -16.0+.4*i  0.000  0.     35.  40. 19.4
s  1  0.0025   16.0       0.000  0.     45.  40. 19.4
s  1  0.005    16.4       0.00   0.     60.  40. 19.4

&field
area -.2 -.2 .2 .2
track .2 0 .21 0
track .21 0 .4 0
track .23 0 .4 0
track .2 0 .2 .2
track .2 0 .2 .01
track .2 0.01 .2 0.2
track .2 0.02 .2 0.2

&optimise
area 0 -.2 .4 .2

&magnetic
components 0. {B} 0. tesla

&gas
Global gas_file=`{GAS}_B{B*10}_P{p}_T{t}.DAT`
* opt gas-pl
  Call inquire_file(gas_file,exist)
  If exist Then
     Say "Gas file {gas_file} exists, retrieving ..."
     get {gas_file}
  Else
     Say "Gas file {gas_file} not found, exit ..."
     &quit
  Endif

opt nogas-pl

&drift
lines 11000
area -0.2 -0.2 .2 .2
select 43

> {OFILE}

* The C's in the output are required for the method of read in used in MOFIA.
*In GEANT the file is read in with a set number of comment lines ignored at the head of the file. If more comment lines are added, then the code will have to change.

say "C STRs generated by {GARFUSER}"
say "C Voltage= {VOLT} Bfield={B} Grid Size={gridsize}"
say "C Gas file used is {gas_file}"
say "C Pressure= {p} Temperature= {t} "

*Note on the parameters for the area command.
*They are offset from the expected 0.0 0.0 0.2 0.2 by 0.0001. This was done as a result of GARFIELD having trouble calculating Drift Times along the planes y=0.0
*and y=0.2 Values obtained from this slightly offset orientation, are treated as though they are in fact ranging from 0.0 to 0.2. At this time, I do not believe that any
*significant changes are occuring as a result of this tiny offset.

grid {gridsize} {gridsize}
area -0.0001 -0.0001 0.1999 0.1999
Table table

>
&quit