!! PHYSICA command file
!! Wire tension analysis. 
!! Adapted version of Youri's script.
!!
!! It's assumed that 15um sense wires are protected by
!! 25um and then 50um wires at each edge.
!! (E.g. for a DC plane wires 1 & 84, 2 & 83 are guard ones.)
!!
!! $Id: wp_tensions.pcm,v 1.3 2001/03/10 01:31:18 andr Exp $

ORIEN   por

pi= ACOS(-1.)
k=  1000/9.806

FILE=` '
inquire `enter file name:' FILE

READ FILE  n t l

nwires = last(n)

d(1:nwires)= 15
rho(1:nwires) =  19.3

!! ================================================================
!! DC/PC specific parameters
!! DC always has 84 wires

IF (84 = nwires) THEN GOTO DC_WIRES

!! PC wire parameters go here
    d(1) = 75
    d(nwires) = 75

    d(2) = 50
    d(nwires-1) = 50

    d(3) = 25
    d(nwires-2) = 25
    
    rho(1)  =  8.96
    rho(2)  =  8.96
    rho(nwires)=  8.96
    rho(nwires-1)=  8.96


GOTO WIRES_END
!! ================
DC_WIRES:
    d(1)= 50
    d(2)= 25
    d(nwires-1)=25
    d(nwires)=50
    
    rho(1)  =  8.96
    rho(nwires)=  8.96

WIRES_END:

!! ================================================================

rho= rho*1.e3
t= t*1.e-3 ! ms to seconds
l= l*1.e-3 ! milimeters to meters
d= d*1.e-6 ! um to meters

DO i= n
!! length is read from the file -- don't recalc
!!!!!  l(i)=2*SQRT(r**2-((i-1)*stp-l0)**2)+0.003
  f(i)= pi*rho(i)*(l(i)*d(i)/t(i))**2*k
ENDDO

WINDOW 3   10 50 90 90
SET nsxinc 10
SET nsyinc 10
SET %ytics -0.5
SET %yticl -1
SET %xtics -0.5
SET %xticl -1
SET %xnumsz 3
SET %ynumsz 3
SET %txthit 8


tens_max = MAX(f)

SET histyp 1
SET linthk 3
LABEL\X `Wire number'
LABEL\Y `Tension, g'
SCALE 0 nwires+5 6 0 INT(tens_max+15.) 4 
! COLOUR 1
GRAPH\axes

SET linthk 6
GRAPH\-axes n f

! STATISTIC f fmean\mean frms\rms

SET linthk 3
SET
    %txthit 4
    %xloc 50
    %yloc 99
    txtang 0
    cursor -2

SET
    %txthit 3
    %xloc 50
    %yloc 94
    txtang 0
    cursor -2

!!! TEXT `Calculated wire lengths '

TENHIST:

WINDOW 4   10 5 90 50
!WINDOW 9    20 30 80 80
SET histyp 1
SET nsxinc 5
SET nsyinc 5


SET linthk 6
SET 
   %txthit 15

!! ================================================================
IF ( nwires = 84 ) THEN GOTO DC_BINS
    BIN\nbins f(4:nwires-3) fbin1 fcount1 80 0 40
GOTO BINS_END
DC_BINS:
    BIN\nbins f(3:nwires-2) fbin1 fcount1 80 0 40
BINS_END:
!! ================================================================

count_max = MAX(fcount1)
SCALE 25 40 3 0 INT(1.3*count_max) 6

GRAPH\noaxes  fbin1 fcount1

LABEL\Y ` N '
LABEL\X `Sense wire tension, g '
SET linthk 3
GRAPH\axes

!! ================================================================
IF ( nwires = 84 ) THEN GOTO DC_STAT
    STATISTIC f[4:nwires-3] fmean\mean 
    fr=f[4:nwires-3]-fmean
GOTO STAT_END
DC_STAT:
    STATISTIC f[3:nwires-2] fmean\mean 
    fr=f[3:nwires-2]-fmean
STAT_END:
!! ================================================================

STATISTIC fr frms\rms

xloc=65
yloc=85
 set
  %xloc xloc
  %yloc yloc
  %txthit 2.5
   cursor -1

 text `mean='//rchar(fmean,`f4.1')//`g'
  yloc=yloc-8
 set
  %yloc yloc
            
text `rms='//rchar(frms,`f5.2')//`g'

SET linthk 1
SET
    %txthit 2.
    %xloc 75
    %yloc 1
    cursor -1