!! PHYSICA command file.
!! Wire position analysis.
!! Adapted from Wayne's script (Sept 19/2000, filename u8stat.com)
!!
!! You supply frame data in a file.
!! It calculates spread in x and u data.
!!
!! $Id: wp_pos.com,v 1.3 2001/05/15 02:16:52 andr Exp $

cl
disable journal

file=` '
inquire `enter filename >' file

title_line = `global title'
inquire `enter global title >' title_line

read file x1 u1 x2 u2

NW = last(x1)

x=(x1+x2)/2.0
u=(u1+u2)/2.0
! list x1 x2 x
! list u1 u2 u
xerr[1:NW]=x1-x
xerr[NW+1:2*NW]=x2-x
uerr[1:NW]=u1-u
uerr[NW+1:2*NW]=u2-u

orientation portrait
!title
window 0
 set
  %xloc   50
  %yloc   97
  %txthit  2
   txtang  0
   cursor -2

 text title_line
 set cursor 1
window 3
bin\nbins  xerr xbin xcount 21 -.0105 .0105
! list xbin xcount
label\xaxis `xerr mm'
label\yaxis `number'
graph\histogram xbin xcount
statistics xerr xmin\min xi\imin xmax\max xm\imax xsig\sdev
show xmin xi xmax xm xsig
xloc=75
yloc=85
 set
  %xloc xloc
  %yloc yloc
   cursor -1

 text `<sigma>='//rchar(xsig,`f7.4')
yloc=yloc-8
 set
  %yloc yloc

 text `min='//rchar(xmin,`f7.4')
yloc=yloc-8
 set
  %yloc yloc

 text `max='//rchar(xmax,`f7.4')
 set cursor 1
window 4
bin\nbins uerr ubin ucount 21 -.0105 .0105
! list xerr uerr
! list ubin ucount
label\xaxis `uerr mm'
label\yaxis `number'
graph\histogram ubin ucount
statistics uerr umin\min ui\imin umax\max um\imax usig\sdev
show umin ui umax um usig
xloc=75
yloc=85
 set
  %xloc xloc
  %yloc yloc
   cursor -1

 text `<sigma>='//rchar(usig,`f7.4')
yloc=yloc-8
 set
  %yloc yloc

 text `min='//rchar(umin,`f7.4')
yloc=yloc-8
 set
  %yloc yloc

 text `max='//rchar(umax,`f7.4')
 set cursor 1